Chapter 17 – Communicating with Other Applications

# Objectives:

* Understanding Microsoft’s Evolving Object Model
* Using Automation
* Using the Shell Command
* Using Sendkeys
* Other Related Commands
* The Environment Class
* The Application Class
* Calling APIs
* The Clipboard

This chapter will examine how to communicate with other applications. Part of what has made Visual Basic such a powerful programming language is its ability to harness the functionality that's present in other applications. This chapter will look at working with other application's object models.

In addition, the chapter will cover the various commands related to starting up and executing other programs from within Visual Basic. VB.NET also provides two classes, the environment class and the application class, to assist in this interprocess communication.

Finally, the chapter will end with a discussion of how to perform low level operating system (O/S) API calls. The Application Programmer Interface extends the capabilities of VB.NET by allowing a developer access to the functionality built into the Windows O/S.

# Microsoft’s Evolving Object Model

When Microsoft Windows 1.0 came out very few cared. In fact, Microsoft probably just threw something together to compete with the Macintosh's graphical user interface. Windows 1.0 was very slow and clunky, running off of 5 ¼" floppy disks. Most computers at the time had a high resolution mode of 640 x 480 with 2 colors. You can see why most people were happy with good old DOS.

With the advent of Windows version 2.0, Microsoft created a much more solid system that ran on top of DOS, had multiple colors and lived on a user's hard drive. One of the more dramatic additions to Windows was the fact that Microsoft provided the capability for two applications to communicate with one another through DDE, or Dynamic Data Exchange. Essentially one application was set up to be the DDE Server and another application could serve as the DDE Client. The two applications could perform some simply data exchanges, typically text based. However, this was the start of cut and copy editing between applications, which up to this point was not a common place event.

Windows 3.0 introduced a more mature technology, OLE, or Object Linking and Embedding, where one application could host a document that had been created by another application. For example, you could embed an Excel spreadsheet into Word. This provided great functionality for users depending on how you used OLE. It was possible to paste in (embed) a copy of a foreign document, and if the user wanted to change that copy, all he or she had to do was double-click on it. The original application that created the foreign document would be started up, allowing for changes to be made. The other type of control in Windows version 3.0 was linking, in which a user would perform a "paste special" command to create just a link to the foreign document in the host document.

You may be wondering that the difference is between linking and embedding. In linking, there is only one copy of a document that ever exists. Any documents that have a link to the foreign document simply point to that one copy. If the user changes the foreign document in any way, the single copy is altered. Therefore, if the user starts up the application that natively created the foreign document and modifies the document, the next time that a document which has a link to the foreign document is opened, the linked document will automatically show the new, changed version.

Embedding documents makes multiple copies of the same document. If you embed an Excel spreadsheet in Word, essentially another copy of the spreadsheet is made: you have the original spreadsheet and a copy in Word. Unfortunately, the two spreadsheets do not automatically synchronize if you make changes to one or the other. Therefore if you change the original spreadsheet, you would have to re-embed it in Word to show the updated changes. This is why many people prefer linking over embedding.

Windows 95 introduced the world to COM, or the Common Object Model (there is some confusion as to whether the C in COM stands for Common or Component). COM is a binary standard that defines interfaces to components so that any programming language can access and use COM objects without worrying about how the COM object was created. Microsoft has changed many of their applications including VB, the Internet Explorer and the Microsoft Office Suite to be built on large COM models so that the applications and their components are largely reusable by other applications. Microsoft continued along this line of communication with COM+ and DCOM, where DCOM refers to Distributed COM. The DCOM model allows for objects to be accessible anywhere on a network, where as the original COM model required objects to be loaded on the user’s local computer.

The .NET architecture brought along an entirely different object model than that which sat underneath pre-.NET technologies. In .NET, COM controls are pretty much passé, while their new counterparts are known as .NET framework components. Here's a basic diagram that shows how the .NET architecture is comprised.

Visual Basic C++ C# F# …

Common Language Specification (CLS)

ASP.NET Windows Forms

Data and XML

Base Class Library (BCL)

Common Language Runtime (CLR)

Windows API COM+ Services

Now this isn’t to say that you can't use COM components in .NET. Microsoft just doesn't make any guarantees that the COM components will work. From personal experience I can tell you that many COM components do work just fine. There are a couple I've run across though, that would not work right. We will examine how to create .NET framework components in a couple chapters down the road.

# Using Automation

As we already mentioned, COM (DCOM and COM+) is Microsoft’s preferred way of providing application and component interoperability. As of this writing of these notes, this still hasn't changed – Microsoft Office 2012 still has a COM object model available.


The access to the COM models that make up applications and the ability to programmatically manipulate them is known as automation in Visual Basic. Almost all modern applications have two things that VB programmers like:

1. Most applications have the ability to allow users to create macros or write programs in VBA (Visual Basic for Applications). This allows a developer to reuse their VB skills and to add needed functionality to existing applications.
2. Most applications have large COM models built in. This allows the application to be used and manipulated through code in Visual Basic. For example, instead of writing code in a VB application to generate mailing labels, Microsoft Word could be called to do the work instead.


Some examples of applications that we can access via COM include Word, Excel, Access, PowerPoint, Outlook, Internet Explorer, Visio, Adobe Acrobat Creator and Photoshop, just to name a few. You'll notice that the list is not just Microsoft exclusive – many companies have bought into the COM view and export the object models of their applications for developers to tie into.

Now that we've gone through the mechanics of what automation is, let’s see an example of it. We will write a VB application that starts up Microsoft Word and writes some text in a new Word document. Obviously to execute this application, you will need to have Microsoft Word available – in fact, you will need Microsoft Office loaded to execute most of the applications in this chapter.

All that we need to do to use Word is to provide a reference to the Microsoft Word Object Library. In case you forgot how to do that, select the Project🡪Add Reference menu selection. Next click on the COM tab and scroll down in the list box to Microsoft Word Object Library and then press Select (I have 14.0 which is Word 2010 – use the newest version you have available to you).:



The form for the application simply has one command button on it. Here’s a screenshot of the application running:



Here’s the code for the application:

'Chapter 17 - Program 1

'Even through we added a reference to the DLL, we want

'to be able to work with the high level pieces without

'writing out the class names long form

Imports Microsoft.Office.Interop

Public Class Form1

'Create a variable that will eventually point to Word

Dim aWordDoc As Word.Application

Private Sub Button1\_Click(sender As Object, e As EventArgs) Handles

Button1.Click

'Create a new instance of Word from within our application

'This will actually start Word up.

aWordDoc = New Word.Application()

'Set the Visible property to true if you want to see Word

'running

aWordDoc.Visible = True

'Add a new document

aWordDoc.Documents.Add()

'Set the font size to 20

aWordDoc.Selection.Font.Size = 20

'Set the font style to italic

aWordDoc.Selection.Font.Italic = True

'Type some information to the document

aWordDoc.Selection.TypeText("Hello -- this data is" \_

& " coming to you live from VB")

'We could save the Word document with this command:

'aWordDoc.Documents(1).SaveAs(“c:\mydoc.doc”)

'We should then quit the application, but if I quit in this app

'you wouldn’t see anything

'aWordDoc.Quit

'set aWordDoc = Nothing

End Sub

End Class

That was pretty simple – the toughest part is navigating the object model to get the application to do what you want it to. Again, if you want more on the details of the object model, consult the MSDN documentation – the Microsoft Office object models are documented there.

Let’s write another application that’s easy to work with: Excel. Remember that you will need to add a reference to the Microsoft Excel Object Library!

Here’s the code for our Excel automation program. We'll do a couple of different things in this application. We will check to see if Excel is already running in memory before we simply start another copy up. We will also close the Excel spreadsheet down when we are done with our program. You'll see that Excel will ask if you want to save the changes to the worksheet that we created before closes, just like you would expect if you were using Excel yourself.

'Chapter 17 - Program 2

Imports Microsoft.Office.Interop

Public Class Form1

Private Sub Button1\_Click(sender As Object, e As EventArgs) Handles

Button1.Click

Dim CheckExcel As Object

Dim anExcelDoc As Excel.Application

Dim intLoop As Integer

'Check to see if Excel is already loaded in memory

Try

CheckExcel = GetObject(, "Excel.Application")

Catch Ex As Exception

'Excel was not running, so we got an error

End Try

If CheckExcel Is Nothing Then

'Create a new instance of Excel

anExcelDoc = New Excel.Application()

anExcelDoc.Visible = True

Else

anExcelDoc = CheckExcel

anExcelDoc.Visible = True

End If

'Add a new workbook and a new sheet

anExcelDoc.Workbooks.Add()

anExcelDoc.Sheets.Add()

'Put some data on the sheet

For intLoop = 1 To 5

anExcelDoc.Cells(intLoop, 1) = 100 \* intLoop

Next

MessageBox.Show("All data has been filled in")

'Throw some statistical information on the sheet

anExcelDoc.Cells(6, 1) = "Ave:"

anExcelDoc.Cells(6, 2) = "=average(a1..a5)"

anExcelDoc.Cells(7, 1) = "Min:"

anExcelDoc.Cells(7, 2) = "=min(a1..a5)"

anExcelDoc.Cells(8, 1) = "Max:"

anExcelDoc.Cells(8, 2) = "=max(a1..a5)"

anExcelDoc.Cells(9, 1) = "Stdev"

anExcelDoc.Cells(9, 2) = "=stdev(a1..a5)"

MessageBox.Show("All statistical data is now available")

'Clean things up

anExcelDoc.Quit()


anExcelDoc = Nothing

End Sub

End Class

You will need to hop back and forth between your application and the Excel sheet to see the message boxes as they pop up. Remember that the message boxes are triggered by your application and not Excel. These were put in to pause the application and help you visualize what’s going on.

Here’s a screenshot of the Excel application in progress. Notice the application is the small "Form1" window in the upper left hand corner. The message box that has appeared belongs to the application, while the remainder of the screen is Excel.



# Using the Shell Command

The Shell method can be used to run another application that's external to your VB application. If the second application successfully starts up, the application’s process ID number will be returned. The Shell method is located in the Microsoft.VisualBasic.Interaction class.

The syntax for the Shell command is Shell *pathname [,windowstyle] [,wait]*, where the *windowstyle* is a constant from the AppWinStyle namespace, and *wait* refers to a Boolean value that indicates whether or not the Shell should wait for the program that is to be executed to complete before closing the window that the program runs in.

Here are the various window styles that you have available to you. Remember to preface any style with AppWinStyle. before the style name.

|  |  |
| --- | --- |
| *Style* | *Purpose* |
| Hide | The new application window is hidden |
| MaximizedFocus | The new application is shown maximized |
| MinimizedFocus | The new application is shown minimized |
| MinimizedNoFocus | The new application is shown minimized but with no focus |
| NormalFocus | The new application is shown in its original size and position |
| NormalNoFocus | The new application is shown normal size but with no focus |

Here’s the code for a sample application that will use the Shell method to execute a DOS command window, the FTP program and Notepad. After each is started, a message box will appear that provides the process ID number of each program.

Public Class Form1

'Chapter 17 - Program 3

Private Sub Button1\_Click(sender As Object, e As EventArgs) Handles

Button1.Click

'These variables will hold the process ID numbers of

'the two programs we are going to run.

Dim intResult1 As Integer

Dim intResult2 As Integer

Dim intResult3 As Integer

'Start up a command prompt...you may have to modify this

'based on your operating system.

'For Windows 2000 and newer

intResult1 = Shell("cmd.exe", AppWinStyle.MaximizedFocus)

MessageBox.Show("cmd.exe = " & intResult1)

'For older windows

'intResult1 = Shell("command.com", AppWinStyle.MaximizedFocus)

'MessageBox.Show("command.com = " & intResult1)

'Start up FTP

intResult2 = Shell("ftp.exe", AppWinStyle.NormalFocus)

MessageBox.Show("ftp.exe = " & intResult2)

'Start up Notepad


intResult3 = Shell("notepad.exe", AppWinStyle.NormalFocus)

MessageBox.Show("Notepad.exe = " & intResult2)

End Sub

End Class

Here’s a screenshot of the Shell application.



The process ID number that each Shelled program receives is provided by the operating system. The number will not be the same each time you Shell an application.

# Using SendKeys

Another class that is handy to work with when using the Shell method is the SendKeys class. SendKeys is used to simulate keyboard entry to an application. The SendKeys.Send method sends its keystrokes to the application that has the focus.

The syntax for the appropriate methods in the SendKeys class is SendKeys.Send(*chars to send*) or SendKeys.SendWait(*chars to send*). If SendWait is used, SendKeys will wait until any processes that might by started by SendKeys handle the keystrokes that have been sent before passing control back to the VB procedure that performed the SendWait.

Here’s an example program that launches the Windows calculator program, and then performs the sequence to add 5 + 3 using the Send method.

'Chapter 17 - Program 4

Public Class Form1

Private Sub Button1\_Click(sender As Object, e As EventArgs) Handles

Button1.Click

'Execute the Calculator program

Shell("calc.exe", vbMaximizedFocus)

'Wait 1 second before proceeding to

'give calc enough time to load up and

'become ready

System.Threading.Thread.Sleep(1000)

'Start sending keys

SendKeys.SendWait("C")

'Send the value 5

SendKeys.Send("5")

'Send the + symbol, but we have to use the

'special value for + since the symbol itself has

'a special meaning in SendKeys -- see the MSDN

'help for more information

SendKeys.Send("{ADD}")

'Send the value 3

SendKeys.Send("3")


'Send the = to do the math

SendKeys.Send("=")

End Sub

End Class

Here’s a screen shot with the results of the addition:



As you learned in the code of the above application, there are some symbols that have special meanings within SendKeys. Here is a list of the special characters that can be sent in SendKeys:

|  |
| --- |
| *Special Characters* |
| + placed before some other character means Shift |
| ^ placed before some other character means Ctrl |
| % placed before some other character means Alt |
| ~ means Enter |
| {Backspace}, {Bs} or {Bksp} |
| {Break} |
| {CapsLock} |
| {Del},{Delete} |
| {Down} |
| {End} |
| {Enter} |
| {Esc} |
| {F1} … {F12} |
| {Help} |
| {Home} |
| {Ins},{Insert} |
| {Left} |
| {Numlock} |
| {Pgdn} |
| {Pgup} |
| {Right} |
| {Scrolllock} |
| {Tab} |
| {Up} |

# Other Related Commands

This chapter has focused so far on examining how to interact with object models in other applications through automation and system level entities such as remote program execution and communication with SendKeys. There are several other methods in the Microsoft.VisualBasic.Interaction class that you might find useful when performing this type of work. Remember to preface each method with the namespace's name.

## AppActivate

Switches focus to the specified application. The syntax is AppActivate(*"Window Title"*) or AppActivate(*processIDNumber*). The first syntactic example activates an application based on the application's window title while the second example activates an application based on the application's process ID.

## Beep

Makes the system speaker beep. The syntax is simply Beep.

## CallByName

Sets and gets properties and invokes methods at runtime by providing arguments to the CallByName method. Here are the different forms of syntax for the CallByName method:

*To set a property:*

CallByName(*object or control*, *property*, CallType.Set*, value to place in property*)

*To get a property:*

CallByName(*object or control*, *property*, CallType.Get)

*To invoke a method:*

CallByName(*object or control*, *method*, CallType.Method)

Here's an example of setting the caption on a command button and then making the command button hide.

'We have to import the following namespace

Imports Microsoft.VisualBasic.CallType

'.

'.

'.

' Set the Text property on a command button

CallByName(Command1, "Text", CallType.Set, "Push Me")

' Retrieve the text property

MessageBox.Show(CallByName(Command1, "Text", CallType.Get))

' Make the command button hide itself

CallByName(Command1, "Hide", CallType.Method)

## Command

Returns the argument portion of the command line that was used to launch VB or a VB developed application. The syntax for this is simply Command and a string will be returned.

## CreateObject

Creates and returns a reference to a COM object.

## Environ

Returns the operating system environment variables as strings. This is a compatibility feature from pre-.NET; you should now use the VB.NET Environment class which will be discussed below.

## Registry Settings

The following commands are related to manipulation of the registry, which is the storage mechanism that Windows uses to keep information about hardware, applications, device drivers and so forth:

### DeleteSetting

Deletes a registry section or key setting. The syntax is DeleteSetting (*ApplicationName*, [*Section*], [*Key*]).

### GetSetting

Gets a registry key setting. The syntax is GetSetting (*ApplicationName*, [*Section*], [*Key*]).

### GetAllSettings

Returns all settings related to an application's registry settings in a list. The syntax is GetAllSettings (*ApplicationName*).

### SaveSetting

Saves a registry setting to the registry. The syntax is SaveSetting (*ApplicationName*, *Section*, *Key*, *Setting*).

# Using the Environment Class

The *Environment* class can be used to both access and set information that is related to the operating system. It is much more powerful than the pre-.NET Environ function that simply returned environment strings.

Let's take a look at an application that prints out information about the current directory, the command line, the operating system version, the computer's name, the current path and all of the environment variables that have been set.

'Chapter 17 - Program 5

Public Class Form1

Private Sub Form1\_Load(sender As Object, e As EventArgs) Handles MyBase.Load

Dim strMessage As String

Dim myEntry As DictionaryEntry

'Get basic information from the environment

strMessage &= "Current directory is " & Environment.CurrentDirectory &

vbCrLf

strMessage &= "Command line launched " & Environment.CommandLine & vbCrLf

strMessage &= "O/S Platform " & Environment.OSVersion.Platform & vbCrLf

strMessage &= "Machine Name " & Environment.MachineName & vbCrLf

MessageBox.Show(strMessage)

'Expand some environment variables with the values

strMessage = "CPU is %PROCESSOR\_LEVEL% Path is %Path%"

MessageBox.Show(Environment.ExpandEnvironmentVariables(strMessage))

'Print out all environment variables

strMessage = ""

For Each myEntry In Environment.GetEnvironmentVariables

strMessage &= myEntry.Key & " = " & myEntry.Value & vbCrLf


Next

MessageBox.Show(strMessage)

End Sub

End Class

Here's a screenshot showing the details of all the environment variables:



Here are the properties of the Environment Class:

|  |  |
| --- | --- |
| Property | Description |
| [CommandLine](http://msdn.microsoft.com/en-us/library/system.environment.commandline.aspx) | Gets the command line for this process. |
| [CurrentDirectory](http://msdn.microsoft.com/en-us/library/system.environment.currentdirectory.aspx) | Gets or sets the fully qualified path of the current working directory. |
| [CurrentManagedThreadId](http://msdn.microsoft.com/en-us/library/system.environment.currentmanagedthreadid.aspx) | Gets a unique identifier for the current managed thread. |
| [ExitCode](http://msdn.microsoft.com/en-us/library/system.environment.exitcode.aspx) | Gets or sets the exit code of the process. |
| [HasShutdownStarted](http://msdn.microsoft.com/en-us/library/system.environment.hasshutdownstarted.aspx) | Gets a value indicating whether the common language runtime (CLR) is shutting down. |
| [Is64BitOperatingSystem](http://msdn.microsoft.com/en-us/library/system.environment.is64bitoperatingsystem.aspx) | Determines whether the current operating system is a 64-bit operating system. |
| [Is64BitProcess](http://msdn.microsoft.com/en-us/library/system.environment.is64bitprocess.aspx) | Determines whether the current process is a 64-bit process. |
| [MachineName](http://msdn.microsoft.com/en-us/library/system.environment.machinename.aspx) | Gets the NetBIOS name of this local computer. |
| [NewLine](http://msdn.microsoft.com/en-us/library/system.environment.newline.aspx) | Gets the newline string defined for this environment. |
| [OSVersion](http://msdn.microsoft.com/en-us/library/system.environment.osversion.aspx) | Gets an [OperatingSystem](http://msdn.microsoft.com/en-us/library/system.operatingsystem.aspx) object that contains the current platform identifier and version number. |
| [ProcessorCount](http://msdn.microsoft.com/en-us/library/system.environment.processorcount.aspx) | Gets the number of processors on the current machine. |
| [StackTrace](http://msdn.microsoft.com/en-us/library/system.environment.stacktrace.aspx) | Gets current stack trace information. |
| [SystemDirectory](http://msdn.microsoft.com/en-us/library/system.environment.systemdirectory.aspx) | Gets the fully qualified path of the system directory. |
| [SystemPageSize](http://msdn.microsoft.com/en-us/library/system.environment.systempagesize.aspx) | Gets the amount of memory for an operating system's page file. |
| [TickCount](http://msdn.microsoft.com/en-us/library/system.environment.tickcount.aspx) | Gets the number of milliseconds elapsed since the system started. |
| [UserDomainName](http://msdn.microsoft.com/en-us/library/system.environment.userdomainname.aspx) | Gets the network domain name associated with the current user. |
| [UserInteractive](http://msdn.microsoft.com/en-us/library/system.environment.userinteractive.aspx) | Gets a value indicating whether the current process is running in user interactive mode. |
| [UserName](http://msdn.microsoft.com/en-us/library/system.environment.username.aspx) | Gets the user name of the person who is currently logged on to the Windows operating system. |
| [Version](http://msdn.microsoft.com/en-us/library/system.environment.version.aspx) | Gets a [Version](http://msdn.microsoft.com/en-us/library/system.version.aspx) object that describes the major, minor, build, and revision numbers of the common language runtime. |
| [WorkingSet](http://msdn.microsoft.com/en-us/library/system.environment.workingset.aspx) | Gets the amount of physical memory mapped to the process context. |

Here are the methods:

|  |  |
| --- | --- |
| Method | Description |
| [Exit](http://msdn.microsoft.com/en-us/library/system.environment.exit.aspx) | Terminates this process and gives the underlying operating system the specified exit code. |
| [ExpandEnvironmentVariables](http://msdn.microsoft.com/en-us/library/system.environment.expandenvironmentvariables.aspx) | Replaces the name of each environment variable embedded in the specified string with the string equivalent of the value of the variable, then returns the resulting string. |
| [FailFast(String)](http://msdn.microsoft.com/en-us/library/ms131100.aspx) | Immediately terminates a process after writing a message to the Windows Application event log, and then includes the message in error reporting to Microsoft. |
| [FailFast(String, Exception)](http://msdn.microsoft.com/en-us/library/dd289240.aspx) | Immediately terminates a process after writing a message to the Windows Application event log, and then includes the message and exception information in error reporting to Microsoft. |
| [GetCommandLineArgs](http://msdn.microsoft.com/en-us/library/system.environment.getcommandlineargs.aspx) | Returns a string array containing the command-line arguments for the current process. |
| [GetEnvironmentVariable(String)](http://msdn.microsoft.com/en-us/library/77zkk0b6.aspx) | Retrieves the value of an environment variable from the current process. |
| [GetEnvironmentVariable(String, EnvironmentVariableTarget)](http://msdn.microsoft.com/en-us/library/y6k3c7b0.aspx) | Retrieves the value of an environment variable from the current process or from the Windows operating system registry key for the current user or local machine. |
| [GetEnvironmentVariables](http://msdn.microsoft.com/en-us/library/1h5xxewc.aspx) | Retrieves all environment variable names and their values from the current process. |
| [GetEnvironmentVariables(EnvironmentVariableTarget)](http://msdn.microsoft.com/en-us/library/40df59yb.aspx) | Retrieves all environment variable names and their values from the current process, or from the Windows operating system registry key for the current user or local machine. |
| [GetFolderPath(Environment.SpecialFolder)](http://msdn.microsoft.com/en-us/library/14tx8hby.aspx) | Gets the path to the system special folder that is identified by the specified enumeration. |
| [GetFolderPath(Environment.SpecialFolder, Environment.SpecialFolderOption)](http://msdn.microsoft.com/en-us/library/dd992682.aspx) | Gets the path to the system special folder that is identified by the specified enumeration, and uses a specified option for accessing special folders. |
| [GetLogicalDrives](http://msdn.microsoft.com/en-us/library/system.environment.getlogicaldrives.aspx) | Returns an array of string containing the names of the logical drives on the current computer. |
| [SetEnvironmentVariable(String, String)](http://msdn.microsoft.com/en-us/library/z46c489x.aspx) | Creates, modifies, or deletes an environment variable stored in the current process. |
| [SetEnvironmentVariable(String, String, EnvironmentVariableTarget)](http://msdn.microsoft.com/en-us/library/96xafkes.aspx) | Creates, modifies, or deletes an environment variable stored in the current process or in the Windows operating system registry key reserved for the current user or local machine. |

# Using the Application Class

The Application class provides many properties, methods and events that relate to the execution of a particular application. Part of the Application class deals with thread-related issues. We will examine threads in an upcoming chapter.

Let's begin by taking a look at the properties, methods and events available inside of the class, starting with the properties:

|  |  |
| --- | --- |
| *Property* | *Purpose* |
| AllowQuit | Gets a value indicating whether the caller can quit this application |
| CommonAppDataPath | Provides the path of application data that is shared among all users. |
| CommonAppDataRegistry | Provides the key of the application data that is shared among all users. |
| CompanyName | Provides the company name that the application has been developed by. |
| CurrentCulture | Provides culture information about the current thread. |
| CurrentInputLanguage | Provides the current input language for the current thread. |
| ExecutablePath | Provides the complete path and filename of the executable. |
| LocalUserAppDataPath | Gets the path for the application data of a local, non-roaming user. |
| OpenForms | Gets a collection of open forms owned by this application. |
| ProductName | Provides the product name of the running application. |
| ProductVersion | Provides the version number of the running application. |
| RenderWithVisualStyles | Gets a value specifying whether the current application is drawing controls with visual styles. |
| SafeTopLevelCaptionFormat | Gets or sets the format string to apply to top-level window captions when they are displayed with a warning banner. |
| StartupPath | Provides the path of the executable file that started the application. |
| UserAppDataPath | Provides the path of the application data of a local user. |
| UserAppDataRegistry | Provides the key of the application data of a local user. |
| UseWaitCursor | Gets or sets whether the wait cursor is used for all open forms of the application. |
| VisualStyleState | Gets a value that specifies how visual styles are applied to application windows. |

Here are the methods of the Application class:

|  |  |
| --- | --- |
| *Method* | *Purpose* |
| [AddMessageFilter](http://msdn.microsoft.com/en-us/library/system.windows.forms.application.addmessagefilter.aspx) | Adds a message filter to monitor Windows messages as they are routed to their destinations. |
| [DoEvents](http://msdn.microsoft.com/en-us/library/system.windows.forms.application.doevents.aspx) | Processes all Windows messages currently in the message queue. |
| [EnableVisualStyles](http://msdn.microsoft.com/en-us/library/system.windows.forms.application.enablevisualstyles.aspx) | Enables visual styles for the application. |
| [Exit](http://msdn.microsoft.com/en-us/library/ms157894.aspx) | Informs all message pumps that they must terminate, and then closes all application windows after the messages have been processed. |
| [Exit(CancelEventArgs)](http://msdn.microsoft.com/en-us/library/ms223873.aspx) | Informs all message pumps that they must terminate, and then closes all application windows after the messages have been processed. |
| [ExitThread](http://msdn.microsoft.com/en-us/library/system.windows.forms.application.exitthread.aspx) | Exits the message loop on the current thread and closes all windows on the thread. |
| [FilterMessage](http://msdn.microsoft.com/en-us/library/system.windows.forms.application.filtermessage.aspx) | Runs any filters against a window message, and returns a copy of the modified message. |
| [OleRequired](http://msdn.microsoft.com/en-us/library/system.windows.forms.application.olerequired.aspx) | Initializes OLE on the current thread. |
| [OnThreadException](http://msdn.microsoft.com/en-us/library/system.windows.forms.application.onthreadexception.aspx) | Raises the [ThreadException](http://msdn.microsoft.com/en-us/library/system.windows.forms.application.threadexception.aspx) event. |
| [RaiseIdle](http://msdn.microsoft.com/en-us/library/system.windows.forms.application.raiseidle.aspx) | Raises the [Idle](http://msdn.microsoft.com/en-us/library/system.windows.forms.application.idle.aspx) event in hosted scenarios. |
| [RegisterMessageLoop](http://msdn.microsoft.com/en-us/library/system.windows.forms.application.registermessageloop.aspx) | Registers a callback for checking whether the message loop is running in hosted environments. |
| [RemoveMessageFilter](http://msdn.microsoft.com/en-us/library/system.windows.forms.application.removemessagefilter.aspx) | Removes a message filter from the message pump of the application. |
| [Restart](http://msdn.microsoft.com/en-us/library/system.windows.forms.application.restart.aspx) | Shuts down the application and starts a new instance immediately. |
| [Run](http://msdn.microsoft.com/en-us/library/ms157900.aspx) | Begins running a standard application message loop on the current thread, without a form. |
| [Run(ApplicationContext)](http://msdn.microsoft.com/en-us/library/ms157901.aspx) | Begins running a standard application message loop on the current thread, with an[ApplicationContext](http://msdn.microsoft.com/en-us/library/system.windows.forms.applicationcontext.aspx). |
| [Run(Form)](http://msdn.microsoft.com/en-us/library/ms157902.aspx) | Begins running a standard application message loop on the current thread, and makes the specified form visible. |
| [SetCompatibleTextRenderingDefault](http://msdn.microsoft.com/en-us/library/system.windows.forms.application.setcompatibletextrenderingdefault.aspx) | Sets the application-wide default for the UseCompatibleTextRendering property defined on certain controls. |
| [SetSuspendState](http://msdn.microsoft.com/en-us/library/system.windows.forms.application.setsuspendstate.aspx) | Suspends or hibernates the system, or requests that the system be suspended or hibernated. |
| [SetUnhandledExceptionMode(UnhandledExceptionMode)](http://msdn.microsoft.com/en-us/library/ms157905.aspx) | Instructs the application how to respond to unhandled exceptions. |
| [SetUnhandledExceptionMode(UnhandledExceptionMode, Boolean)](http://msdn.microsoft.com/en-us/library/ms223898.aspx) | Instructs the application how to respond to unhandled exceptions, optionally applying thread-specific behavior. |
| [UnregisterMessageLoop](http://msdn.microsoft.com/en-us/library/system.windows.forms.application.unregistermessageloop.aspx) | Unregisters the message loop callback made with [RegisterMessageLoop](http://msdn.microsoft.com/en-us/library/system.windows.forms.application.registermessageloop.aspx). |

Events of the Application class:

|  |  |
| --- | --- |
| *Event* | *Purpose* |
| ApplicationExit | This event fires when the application is about to shut down and all of its forms have been closed. |
| EnterThreadModal | Occurs when the application is about to enter a modal state |
| Idle | This event fires after the application has processed all the messages in the input queue and is entering the idle state. |
| LeaveThreadModal | Occurs when the application is about to leave a modal state |
| ThreadException | This event fires when an unhandled thread exception occurs and the event permits the user to continue or abort the application. |
| ThreadExit | This event fires when a thread is about to terminate. |

Let's take a look at a program that shows some of the more commonly used items from the Application class. In particular this program will display information about the application itself: the startup path, the company name and the product name and version.

'Chapter 17 - Program 6

Public Class Form1

Private Sub Button1\_Click(sender As Object, e As EventArgs) Handles

Button1.Click

Dim strMsg As String

'Get some attributes from the Application class

strMsg &= "StartupPath " & Application.StartupPath & vbCrLf

strMsg &= "CompanyName " & Application.CompanyName & vbCrLf

strMsg &= "ProductName " & Application.ProductName & vbCrLf


strMsg &= "ProductVersion " & Application.ProductVersion & vbCrLf

MessageBox.Show(strMsg)

End Sub

End Class

Here's the output from the application:



# Making API Calls

Although VB is very powerful on its own, there are still some things that it cannot do. Fortunately most of what VB cannot do natively, the Windows API (Application Programmer Interface) can. The API is an interface to the Windows operating system itself – the core files that provide the functionality of Windows.

This section is going to show you how to make Windows API calls from VB.NET. This is probably a good place to discuss API calls since we have been concentrating on getting VB to communicate with other applications in this chapter.

These are the main functional categories that make up the Windows API:

1. Windows Management (USER32.DLL) – provides the essential functions to build and manage your applications. All basic I/O goes through this category including mouse and keyboard input and all messages sent to your applications.
2. Graphics Device Interface (GDI32.DLL) – provides the functions you use to manage all supported graphical devices on your system such as the display monitor and printer.
3. System Services (KERNEL32.DLL) – provides the functions that access the resources of the computer and the operating system.
4. Advanced Services (ADVAPI32.DLL) – provides additional functionality in the kernel, access to the registry, services and user accounts.
5. Common Dialog Box Library (COMDLG32.DLL) – file open/save, fonts, color, printing dialog boxes.
6. Common Control Library (COMCTL32.DLL) – this is where the basic controls (textbox, command buttons, listboxes, et cetera) live.
7. Windows Shell (SHELL32.DLL) – this is what allows our applications to access the functionality in the shell.
8. Network Services (NETAPI32.DLL) – this is where we access the various networking capabilities of Windows.

The easiest way to work with API calls is through the Windows API Code Pack for Microsoft .NET Framework. There is a viewer utility that allows you to see the API declarations and data structures are available and can be copied from the clipboard into your VB application.

Let’s write an application that uses the Windows API to get the name of the current user logged onto our computer:

Public Class Form1

'Chapter 17 - Program 7

'Here's the necessary API call to get the current user

'name on the system. I did not type this function in --

'instead I copied it from the API viewer

Declare Function GetUserName Lib "advapi32.dll" Alias \_

"GetUserNameA" (ByVal lpBuffer As String, ByRef nSize As Integer) \_

As Integer

Private Sub Button1\_Click(sender As Object, e As EventArgs) Handles

Button1.Click

Dim RetVal As Integer

Dim UserName As String

Dim Buffer As String

'This is where the user name will be stored

Buffer = New String(CChar(" "), 25)

'Call the API function

RetVal = GetUserName(Buffer, 25)

'Parse out the username

UserName = Strings.Left(Buffer, InStr(Buffer, Chr(0)) - 1)


'Show the username

MessageBox.Show(UserName)

End Sub

End Class

Here is a screenshot of the application in action:




A word of caution needs to be placed here! You can really mess things up on your computer if you’re not careful in VB when making API calls. You could create enough problems that you may have to reformat and reload your system. I provided this section as a simple example so that you would know what API calls are, why they are used and how to perform one. You need to get very good at understanding the parameter information that is expected in an API call and what the API call is for …

I really do not recommend that you blindly try guessing about API calls' purposes or parameters. There are a few books on the market that discuss API calls. My personal favorite is an oldie: Dan Appleman’s Visual Basic Programmer’s Guide to the Win32 API which is published by ZD Press. If you are going to work with the API, this book is a must have! I haven’t seen many .NET books that talk about the API since Microsoft really doesn’t want you messing with it. They have tried to put everything they think you could need into the managed .NET libraries. There are still occasional calls to use the API however and it was a standard piece of programming knowledge required in the pre-.NET days!


Also remember that many calls require integers, longs and so forth – these data types have changed in size from pre-.NET to VB.NET, thus you will have to perform some data conversions in order to get some of the code to work right. Also realize that Win64 and WinRT have completely different APIs, so this is something to take into account when you decide you really think you need to do something via an API call!

# The Clipboard

So everytime you’ve cut, copied or pasted, you’ve used the clipboard. While we are on the subject of communicating between applications, it seems appropriate to visit this concept.



In the example program above, I can press the Copy to Clipboard button to copy whatever is in the application’s textbox to the clipboard. I then hopped over to Notepad and pasted it in there. I can do the opposite as well…



Here’s the code:

Public Class Form1

Private Sub cmdCopy\_Click(sender As Object, e As EventArgs) Handles

cmdCopy.Click

Clipboard.SetText(TextBox1.Text)

End Sub

Private Sub cmdPaste\_Click(sender As Object, e As EventArgs) Handles

cmdPaste.Click

TextBox1.Text = Clipboard.GetText

End Sub

End Class

The clipboard object exposes the following properties and methods:

|  |  |
| --- | --- |
| Name | Description |
| [Clear](http://msdn.microsoft.com/en-us/library/system.windows.forms.clipboard.clear.aspx) | Removes all data from the Clipboard. |
| [ContainsAudio](http://msdn.microsoft.com/en-us/library/system.windows.forms.clipboard.containsaudio.aspx) | Indicates whether there is data on the Clipboard in the [WaveAudio](http://msdn.microsoft.com/en-us/library/system.windows.forms.dataformats.waveaudio.aspx) format. |
| [ContainsData](http://msdn.microsoft.com/en-us/library/system.windows.forms.clipboard.containsdata.aspx) | Indicates whether there is data on the Clipboard that is in the specified format or can be converted to that format. |
| [ContainsFileDropList](http://msdn.microsoft.com/en-us/library/system.windows.forms.clipboard.containsfiledroplist.aspx) | Indicates whether there is data on the Clipboard that is in the [FileDrop](http://msdn.microsoft.com/en-us/library/system.windows.forms.dataformats.filedrop.aspx) format or can be converted to that format. |
| [ContainsImage](http://msdn.microsoft.com/en-us/library/system.windows.forms.clipboard.containsimage.aspx) | Indicates whether there is data on the Clipboard that is in the [Bitmap](http://msdn.microsoft.com/en-us/library/system.windows.forms.dataformats.bitmap.aspx) format or can be converted to that format. |
| [ContainsText](http://msdn.microsoft.com/en-us/library/a3cyzt72.aspx) | Indicates whether there is data on the Clipboard in the [Text](http://msdn.microsoft.com/en-us/library/system.windows.forms.textdataformat.aspx) or [UnicodeText](http://msdn.microsoft.com/en-us/library/system.windows.forms.textdataformat.aspx) format, depending on the operating system. |
| [ContainsText(TextDataFormat)](http://msdn.microsoft.com/en-us/library/t81k888y.aspx) | Indicates whether there is text data on the Clipboard in the format indicated by the specified [TextDataFormat](http://msdn.microsoft.com/en-us/library/system.windows.forms.textdataformat.aspx) value. |
| [GetAudioStream](http://msdn.microsoft.com/en-us/library/system.windows.forms.clipboard.getaudiostream.aspx) | Retrieves an audio stream from the Clipboard. |
| [GetData](http://msdn.microsoft.com/en-us/library/system.windows.forms.clipboard.getdata.aspx) | Retrieves data from the Clipboard in the specified format. |
| [GetDataObject](http://msdn.microsoft.com/en-us/library/system.windows.forms.clipboard.getdataobject.aspx) | Retrieves the data that is currently on the system Clipboard. |
| [GetFileDropList](http://msdn.microsoft.com/en-us/library/system.windows.forms.clipboard.getfiledroplist.aspx) | Retrieves a collection of file names from the Clipboard. |
| [GetHashCode](http://msdn.microsoft.com/en-us/library/system.object.gethashcode.aspx) | Serves as a hash function for a particular type. (Inherited from [Object](http://msdn.microsoft.com/en-us/library/system.object.aspx).) |
| [GetImage](http://msdn.microsoft.com/en-us/library/system.windows.forms.clipboard.getimage.aspx) | Retrieves an image from the Clipboard. |
| [GetText](http://msdn.microsoft.com/en-us/library/kz40084e.aspx) | Retrieves text data from the Clipboard in the [Text](http://msdn.microsoft.com/en-us/library/system.windows.forms.textdataformat.aspx) or [UnicodeText](http://msdn.microsoft.com/en-us/library/system.windows.forms.textdataformat.aspx) format, depending on the operating system. |
| [GetText(TextDataFormat)](http://msdn.microsoft.com/en-us/library/944ft9kf.aspx) | Retrieves text data from the Clipboard in the format indicated by the specified [TextDataFormat](http://msdn.microsoft.com/en-us/library/system.windows.forms.textdataformat.aspx) value. |
| [GetType](http://msdn.microsoft.com/en-us/library/system.object.gettype.aspx) | Gets the [Type](http://msdn.microsoft.com/en-us/library/system.type.aspx) of the current instance. (Inherited from [Object](http://msdn.microsoft.com/en-us/library/system.object.aspx).) |
| [SetAudio(Byte())](http://msdn.microsoft.com/en-us/library/ea51k1k6.aspx) | Clears the Clipboard and then adds a [Byte](http://msdn.microsoft.com/en-us/library/system.byte.aspx) array in the [WaveAudio](http://msdn.microsoft.com/en-us/library/system.windows.forms.dataformats.waveaudio.aspx) format after converting it to a [Stream](http://msdn.microsoft.com/en-us/library/system.io.stream.aspx). |
| [SetAudio(Stream)](http://msdn.microsoft.com/en-us/library/s39c87sa.aspx) | Clears the Clipboard and then adds a [Stream](http://msdn.microsoft.com/en-us/library/system.io.stream.aspx) in the [WaveAudio](http://msdn.microsoft.com/en-us/library/system.windows.forms.dataformats.waveaudio.aspx) format. |
| [SetData](http://msdn.microsoft.com/en-us/library/system.windows.forms.clipboard.setdata.aspx) | Clears the Clipboard and then adds data in the specified format. |
| [SetDataObject(Object)](http://msdn.microsoft.com/en-us/library/5b8kt5z4.aspx) | Clears the Clipboard and then places nonpersistent data on it. |
| [SetDataObject(Object, Boolean)](http://msdn.microsoft.com/en-us/library/cs5ebdfz.aspx) | Clears the Clipboard and then places data on it and specifies whether the data should remain after the application exits. |
| [SetDataObject(Object, Boolean, Int32, Int32)](http://msdn.microsoft.com/en-us/library/ms158293.aspx) | Clears the Clipboard and then attempts to place data on it the specified number of times and with the specified delay between attempts, optionally leaving the data on the Clipboard after the application exits. |
| [SetFileDropList](http://msdn.microsoft.com/en-us/library/system.windows.forms.clipboard.setfiledroplist.aspx) | Clears the Clipboard and then adds a collection of file names in the [FileDrop](http://msdn.microsoft.com/en-us/library/system.windows.forms.dataformats.filedrop.aspx) format. |
| [SetImage](http://msdn.microsoft.com/en-us/library/system.windows.forms.clipboard.setimage.aspx) | Clears the Clipboard and then adds an [Image](http://msdn.microsoft.com/en-us/library/system.drawing.image.aspx) in the [Bitmap](http://msdn.microsoft.com/en-us/library/system.windows.forms.dataformats.bitmap.aspx) format. |
| [SetText(String)](http://msdn.microsoft.com/en-us/library/ydby206k.aspx) | Clears the Clipboard and then adds text data in the [Text](http://msdn.microsoft.com/en-us/library/system.windows.forms.textdataformat.aspx) or [UnicodeText](http://msdn.microsoft.com/en-us/library/system.windows.forms.textdataformat.aspx) format, depending on the operating system. |
| [SetText(String, TextDataFormat)](http://msdn.microsoft.com/en-us/library/tbfb3z56.aspx) | Clears the Clipboard and then adds text data in the format indicated by the specified [TextDataFormat](http://msdn.microsoft.com/en-us/library/system.windows.forms.textdataformat.aspx) value. |